XSLT在IF语句后添加图书价格

XSLT Adding the price of books after an IF Statement

本文关键字：添加 IF 语句 XSLT      更新时间：2023-09-26

不太确定如何做到这一点，因为"sum（）"函数将添加XML页面中的所有值，而不是"if"语句选择的值。

这是XML:

<book>
    <title type="non-fiction">Harry Potter and the Philosophers Stone</title>
    <author>J.K Rowling</author>
    <publisher>Bloomsbury</publisher>
    <year>1997</year>
    <price>12.99</price>
</book>
<book>
    <title type="fiction">The Lord of the Rings</title>
    <author>J. R. R. Tolkien</author>
    <publisher>George Allen and Unwin</publisher>
    <year>1954</year>
    <price>39.99</price>
</book>
<book>
    <title type="non-fiction">The Right Stuff</title>
    <author>Tom Wolfe</author>
    <publisher>Farra, Staus and Giroux</publisher>
    <year>1979</year>
    <price>29.99</price>
</book>

以下是XSLT：

  <xsl:output 
method="html" 
indent="yes" 
version="4.0"
doctype-public="-//W3C//DTD HTML 4.01//EN"
doctype-system="http://www.w3.org/TR/html4/strict.dtd"/>
<xsl:template match="/library">
<html>
<body>
    <xsl:for-each select="book">
        <xsl:if test="title[@type='non-fiction']">
            <xsl:if test="price&lt;30" >
                <p class="title"> <xsl:value-of select="title"/></p>
                <p class="author"> <xsl:value-of select="author"/> </p>
                <p class="price"> <xsl:value-of select="price"/> </p>   
            </xsl:if>
        </xsl:if>
    </xsl:for-each>     
</body>

我想加上符合所有条件的书籍总数。我以为sum函数会这样做，但它会添加所有的书，不管它是否传递了"if"语句。

一种可能性是定义

  • 一个节点集变量，用于保存要打印的所有书籍
  • 然后在设置为打印书籍的节点上循环
  • 并在最后使用sum函数来计算总价

例如

<body>
    <xsl:variable name="books" select="book[title[@type='non-fiction']][price&lt;30]" />
    <xsl:for-each select="$books">
        <p class="title"> <xsl:value-of select="title"/></p>
        <p class="author"> <xsl:value-of select="author"/> </p>
        <p class="price"> <xsl:value-of select="price"/> </p>   
    </xsl:for-each>     
    <p class="total-price"> <xsl:value-of select="sum($books/price)"/> </p>   
</body>

你可以试试这个：

  <xsl:template match="/library" >
  <html>
  <body>
      <xsl:variable name="fiction_lt30" 
          select="book[title[@type='non-fiction'] and price &lt; 30] " />
      <xsl:for-each select="$fiction_lt30">
        <p class="title"> <xsl:value-of select="title"/></p>
        <p class="author"> <xsl:value-of select="author"/> </p>
        <p class="price"> <xsl:value-of select="price"/> </p>   
      </xsl:for-each>     
        <p>total: <xsl:value-of select="sum($fiction_lt30/price)" /></p>
    </body>
</html>
</xsl:template>

这里有一个完整而简短的解决方案：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>
 <xsl:template match="/*">
  <xsl:variable name="vBooks" 
                select="book[title[@type='non-fiction'] and not(price >= 30)]"/>
    <html>
     <body>
       <xsl:apply-templates select="$vBooks"/>
       <p><strong>Total Cost:</strong><span><xsl:value-of 
                                                 select="sum($vBooks/price)"/></span></p>
     </body>
    </html>
  </xsl:template>
  <xsl:template match="book/*[self::title or self::author or self::price]">
   <p class="{name()}"> <xsl:value-of select="."/></p>
  </xsl:template>
</xsl:stylesheet>
相关文章：